1. Hello Guest, selamat datang di Forum WinPoin. Kamu bisa bertanya, berdiskusi, sharing, dan ngobrolin apapun seputar Windows, Windows Phone, PC, Gadget, atau hal seputar Teknologi lainnya. Selamat berkomunitas! ;)

Ask (WSUS Client) Windows tidak bisa update manual Error Code 80244019

Discussion in 'Windows 7' started by Thabrani Abi, Sep 26, 2017.

  1. Thabrani Abi

    Thabrani Abi New Member

    Joined:
    Sep 11, 2017
    Messages:
    18
    HELP

    Dikantor saya semua Laptop pada join domain ke server, dan untuk update di control oleh WSUS, Nah Ceritanya Beberapa Laptop yg ada (win 7) akan di Update manual namun ketika saya klik CHECK FOR UPDATE

    upload_2017-9-26_19-35-14.png



    Maka hasil nya seperti ini, muncul notif Windows could not search for new updates
    dengan error code 80244019

    upload_2017-9-26_19-36-46.png


    Solusi yg sudah saya lakukan namun tidak berhasil :
    * Restart Laptop
    * Restart Service windows update
    * Menjalankan windows update troubleshoot ( fix cuma masih belum bisa update, error tetep muncul )






    Ada yang tau solusi untuk masalah ini ?
     
  2. NubieBytes

    NubieBytes Member

    Joined:
    Sep 6, 2017
    Messages:
    89
    Coba update dengan vb script dulu mas.
    Save script di dalam spoiler ke C:\ beri nama "WUA_UpdatesWSUS.vbs"
    Code:
    '#################################################################################################
    	Const Author				=	"David Segura"
    	Const AuthorEmail			=	"david@segura.org"
    
    '	Reference
    '	https://msdn.microsoft.com/en-us/library/windows/desktop/aa387290(v=vs.85).aspx
    '	https://msdn.microsoft.com/en-us/library/windows/desktop/aa387102(v=vs.85).aspx
    '	https://msdn.microsoft.com/en-us/library/windows/desktop/aa386526%28v=vs.85%29.aspx
    
    '	Usage: cscript WUA_UpdatesWSUS.vbs
    
    '	Scans the computer for Missing Updates with a WSUS Server
    
    '#################################################################################################
    Set UpdateSession = CreateObject("Microsoft.Update.Session")
    UpdateSession.ClientApplicationID = "MSDN Sample Script"
    Set UpdateSearcher = UpdateSession.CreateUpdateSearcher()
    '#################################################################################################
    WScript.Echo "Searching for updates..." & vbCRLF
    
    'https://msdn.microsoft.com/en-us/library/ee897380.aspx
    'Only one option can be used
    'UpdateSearcher.ServerSelection = 0		'ssDefault			Search the default server for updates that match the search criteria.
    'UpdateSearcher.ServerSelection = 1		'ssManagedServer	Search only the managed server for updates that match the search criteria.
    UpdateSearcher.ServerSelection = 2		'ssWindowsUpdate	Search the Windows Update service over the Internet.
    'UpdateSearcher.ServerSelection = 3		'ssOthers			Search another server, to be specified by other means.
    
    Set SearchResult = UpdateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
    '#################################################################################################
    If SearchResult.Updates.Count = 0 Then
        WScript.Echo "There are no applicable updates."
        WScript.Quit
    End If
    '#################################################################################################
    WScript.Echo "List of applicable items on the machine:" & vbCRLF
    
    For I = 0 To SearchResult.Updates.Count-1
        Set update = SearchResult.Updates.Item(I)
        WScript.Echo I + 1 & "> " & update.Title
    Next
    '#################################################################################################
    WScript.Echo vbCRLF & "Creating collection of updates to download:"
    
    Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")
    
    For I = 0 to SearchResult.Updates.Count-1
        Set update = SearchResult.Updates.Item(I)
        addThisUpdate = false
        If update.InstallationBehavior.CanRequestUserInput = true Then
            WScript.Echo I + 1 & "> skipping: " & update.Title & _
            " because it requires user input"
        Else
            If update.EulaAccepted = false Then
                'WScript.Echo I + 1 & "> note: " & update.Title & _
                '" has a license agreement that must be accepted:"
                'WScript.Echo update.EulaText
                'WScript.Echo "Do you accept this license agreement? (Y/N)"
                'strInput = WScript.StdIn.Readline
                'WScript.Echo 
                'If (strInput = "Y" or strInput = "y") Then
                    update.AcceptEula()
                    addThisUpdate = true
                'Else
                '    WScript.Echo I + 1 & "> skipping: " & update.Title & _
                '    " because the license agreement was declined"
                'End If
            Else
                addThisUpdate = true
            End If
        End If
        If addThisUpdate = true Then
            WScript.Echo I + 1 & "> adding: " & update.Title 
            updatesToDownload.Add(update)
        End If
    Next
    '#################################################################################################
    If updatesToDownload.Count = 0 Then
        WScript.Echo "All applicable updates were skipped."
        WScript.Quit
    End If
    '#################################################################################################
    WScript.Echo  vbCRLF & "Would you like to download updates now? (Y/N)"
    strInput = WScript.StdIn.Readline
    WScript.Echo 
    
    If (strInput = "Y" or strInput = "y") Then
    	WScript.Echo vbCRLF & "Downloading updates..."
    
    	Set downloader = updateSession.CreateUpdateDownloader() 
    	downloader.Updates = updatesToDownload
    	downloader.Download()
    
    	Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")
    
    	rebootMayBeRequired = false
    
    	WScript.Echo vbCRLF & "Successfully downloaded updates:"
    
    	For I = 0 To SearchResult.Updates.Count-1
    		set update = SearchResult.Updates.Item(I)
    		If update.IsDownloaded = true Then
    			WScript.Echo I + 1 & "> " & update.Title 
    			updatesToInstall.Add(update) 
    			If update.InstallationBehavior.RebootBehavior > 0 Then
    				rebootMayBeRequired = true
    			End If
    		End If
    	Next
    
    	If updatesToInstall.Count = 0 Then
    		WScript.Echo "No updates were successfully downloaded."
    		WScript.Quit
    	End If
    
    	If rebootMayBeRequired = true Then
    		WScript.Echo vbCRLF & "These updates may require a reboot."
    	End If
    Else
    	Wscript.Quit
    End If
    
    '#################################################################################################
    WScript.Echo  vbCRLF & "Would you like to install updates now? (Y/N)"
    strInput = WScript.StdIn.Readline
    WScript.Echo 
    
    If (strInput = "Y" or strInput = "y") Then
        WScript.Echo "Installing updates..."
        Set installer = updateSession.CreateUpdateInstaller()
        installer.Updates = updatesToInstall
        Set installationResult = installer.Install()
     
        'Output results of install
        WScript.Echo "Installation Result: " & _
        installationResult.ResultCode 
        WScript.Echo "Reboot Required: " & _ 
        installationResult.RebootRequired & vbCRLF 
        WScript.Echo "Listing of updates installed " & _
        "and individual installation results:" 
     
        For I = 0 to updatesToInstall.Count - 1
            WScript.Echo I + 1 & "> " & _
            updatesToInstall.Item(i).Title & _
            ": " & installationResult.GetUpdateResult(i).ResultCode   
        Next
    End If
    Cara jalankannya Win+R untuk buka RUN, lalu di kolom open co-paste, code ini:
    Code:
    cscript C:\WUA_UpdatesWSUS.vbs
    Nanti tinggal jawab Y/N bila ditanya mau download update/tidak (bila update'an ketemu).

    P.S: Klo post² "ASK" yang lain sudah solved, sebaiknya diganti prefix-nya menjadi "SOLVED".
     
  3. Thabrani Abi

    Thabrani Abi New Member

    Joined:
    Sep 11, 2017
    Messages:
    18
    udah saya coba gan, hasil nya stuck disini
    upload_2017-9-27_7-58-2.png
     
  4. NubieBytes

    NubieBytes Member

    Joined:
    Sep 6, 2017
    Messages:
    89
    Laptop terkoneksi dengan internet gak mas?
    Trus coba search di forum ini WUReset.bat atau WUReset script, klo gak salah sih sudah ada yang posting, itu untuk ngereset WU yg mengalami error.

    Itu cara pertama, cara kedua bila cara pertama ga ngefek. Re-install driver LAN dan Chipset.
     
    Last edited: Sep 27, 2017
  5. Thabrani Abi

    Thabrani Abi New Member

    Joined:
    Sep 11, 2017
    Messages:
    18
    Ok sy sudah coba cara ini dan update nya muncul, tetapi update yg muncul update langsung dari microsoft (online) bukan dari WSUS server
     
  6. NubieBytes

    NubieBytes Member

    Joined:
    Sep 6, 2017
    Messages:
    89
    Oops.. saya lupa, itu di script yang saya aktifkan >> "UpdateSearcher.ServerSelection = 2". Untuk ngecek dari server lain kasih tanda petik pada serverselection nomor 2 dan hilangkan tanda petik pada nomor yang lain mas. 0/1/3
     
  7. Thabrani Abi

    Thabrani Abi New Member

    Joined:
    Sep 11, 2017
    Messages:
    18
    Jika saya ingin ngecek dari server WSUS yg ada di tempat saya gimana ? nomor brp yg harus saya masukkan ?
     
  8. NubieBytes

    NubieBytes Member

    Joined:
    Sep 6, 2017
    Messages:
    89
    Klo gak salah sih no. 1. Saya lupa mas, coba aja satu². Bila nihil juga, coba googling "WSUS Offline Update 11.0.1 Generator" di tool ini klik tombol WSUS, isi alamat server lokal.

    Atau mas kunjungi alamat ini, untuk step by step pengaturan di mesin klien.
     
    Last edited: Sep 27, 2017

Share This Page